Disc subtitles, turned into text.

on adding folder items to theFolder after receiving addedItems
	repeat with anItem in addedItems
		set thePath to POSIX path of anItem
		if thePath ends with ".mkv" then
			with timeout of 7200 seconds
				tell application "Captionist"
					set srtFiles to extract subtitles thePath language "eng"
					repeat with srt in srtFiles
						clean subtitles (srt as text) spelling "British"
					end repeat
				end tell
			end timeout
		end if
	end repeat
end adding folder items to

on run {input, parameters}
	set made to {}
	tell application "Captionist"
		with timeout of 7200 seconds
			repeat with f in input
				set made to made & (extract subtitles (POSIX path of f) with overwriting)
			end repeat
		end timeout
	end tell
	return made
end run

set theFilm to POSIX path of (choose file with prompt "Choose a film")
tell application "Captionist"
	with timeout of 7200 seconds
		set german to item 1 of (extract subtitles theFilm language "deu")
		translate subtitles german language "en-GB" with cleaning
	end timeout
end tell

set theFolder to choose folder with prompt "Folder with episodes"
tell application "Finder" to set episodes to (every file of theFolder whose name extension is "mkv") as alias list
tell application "Captionist"
	with timeout of 36000 seconds
		repeat with ep in episodes
			try
				extract subtitles (POSIX path of ep) language "eng"
			end try -- already done: Captionist won't overwrite it
		end repeat
	end timeout
end tell